CREATE OR REPLACE
FUNCTION NDPCAL_PRATO(
   P_CDFILIAL     IN FILIAL.CDFILIAL%TYPE,
   P_CDSERVFILI   IN SERVICO.CDSERVFILI%TYPE,
   P_CDFILAUXPRAT IN PRATO.CDFILAUXPRAT%TYPE,
   P_CDPRATO      IN PRATO.CDPRATO%TYPE,
   P_CDFILCENTPME IN FILIAL.CDFILCENTPME%TYPE DEFAULT NULL,
   P_CDTIPOCARD   IN TIPOCARD.CDTIPOCARD%TYPE DEFAULT NULL,
   P_MERENDA      IN VARCHAR2 DEFAULT 'N')  RETURN  NUMBER
AS
   V_NDPCAL    NUMBER;
   V_PROTLIQU  NUMBER; /* Sum (Protenas) */
   V_CALORIAS  NUMBER; /* VCT */
   V_NPU       NUMBER; /* Sum (Protena x Fator de Clculo) */
BEGIN
   /* ----------------- RETORNA O TOTAL DE CALORIAS DO PRATO ---------------- */
   FOR CUR_CALORIA IN
     (SELECT
           SUM(NP.QTNUTRPROD * QTPRODUTO) * 4 AS PROTEINA,
           SUM(NC.QTNUTRPROD * QTPRODUTO) * 4 AS CARBOIDRATO,
           SUM(NL.QTNUTRPROD * QTPRODUTO) * 9 AS LIPIDEO,
           SUM(NA.QTNUTRPROD * QTPRODUTO) * 7 AS ALCOOL
      FROM (
         /*RECEITA POR SERVIO*/
        SELECT R.CDPRODUTO, P.CDCARBOHIDRA, P.CDPROTEINA, P.CDLIPIDIOS, P.CDALCOOL,
                (10 * NVL(DECODE(PRODFILI.VRPESOUNIDFI, 0, R.VRPESOUNID, PRODFILI.VRPESOUNIDFI), R.VRPESOUNID) * R.QTCALCNUTR) AS QTPRODUTO
            FROM (SELECT MAX(CDCARBOHIDRA) CDCARBOHIDRA, MAX(CDPROTEINA) CDPROTEINA,
                         MAX(CDLIPIDIOS) CDLIPIDIOS, MAX(CDALCOOL) CDALCOOL FROM PARAMGERAL) P,
                 PRODFILI, PRATO P,
                 TABLE (RECEITA_UTIL(P_CDFILIAL, P_CDSERVFILI, P.CDPRATO, P.CDFILAUXPRAT,'0', 'Z', P.CDPRATO,0,0,'N') ) R
           WHERE (P.CDPRATO = P_CDPRATO)
             AND (P.CDFILAUXPRAT = 'P' OR P.CDFILAUXPRAT = P_CDFILIAL)
             AND (R.CDPRATOPAI = P.CDPRATO) 
             AND (R.CDFILAUXPRAT = P.CDFILAUXPRAT)
             AND (PRODFILI.CDFILIAL  = P_CDFILIAL)
             AND (PRODFILI.CDPRODUTO = R.CDPRODUTO)) R,
         NUTRPROD NC, NUTRPROD NP, NUTRPROD NL, NUTRPROD NA
      WHERE
         NP.CDPRODUTO   (+) = R.CDPRODUTO    AND
         NP.CDNUTRIENTE (+) = R.CDPROTEINA   AND
         NC.CDPRODUTO   (+) = R.CDPRODUTO    AND
         NC.CDNUTRIENTE (+) = R.CDCARBOHIDRA AND
         NL.CDPRODUTO   (+) = R.CDPRODUTO    AND
         NL.CDNUTRIENTE (+) = R.CDLIPIDIOS   AND
         NA.CDPRODUTO   (+) = R.CDPRODUTO    AND
         NA.CDNUTRIENTE (+) = R.CDALCOOL
   ) LOOP
      V_CALORIAS := NVL(CUR_CALORIA.CARBOIDRATO,0) + NVL(CUR_CALORIA.LIPIDEO,0) + NVL(CUR_CALORIA.PROTEINA,0) + NVL(CUR_CALORIA.ALCOOL,0);
   END LOOP;

   /* ---------------- RETORNA O TOTAL DE PROTEINAS E O NPU DO PRATO ---------------- */

   FOR CUR_PROTEINA IN
     (SELECT SUM(NPU) NPU FROM (
           SELECT 
             SUM(
                 NP.QTNUTRPROD * 10 * 
                 NVL(DECODE(PRODFILI.VRPESOUNIDFI, 0, R.VRPESOUNID, PRODFILI.VRPESOUNIDFI), R.VRPESOUNID) * 
                 QTCALCNUTR * 
                 NVL((SELECT MAX(N.VRFATCALNDPC)
                        FROM NDPCAL N WHERE INSTR(R.CDPRODUTO, N.CDPRODUTO) > 0), 1) 
                 ) AS NPU
        FROM PRODFILI, NUTRPROD NP, PRATO P,
            TABLE (RECEITA_UTIL(P_CDFILIAL, P_CDSERVFILI, P.CDPRATO, P.CDFILAUXPRAT,'0', 'Z', P.CDPRATO,0,0,'N') ) R
        WHERE (R.CDPRATOPAI = P.CDPRATO)
          AND (P.CDPRATO = P_CDPRATO)
          AND (P.CDFILAUXPRAT = P_CDFILAUXPRAT)
          AND (P.CDFILAUXPRAT = P_CDFILAUXPRAT)
          AND (R.CDFILAUXPRAT = P.CDFILAUXPRAT)
          AND (R.CDPRODUTO       = NP.CDPRODUTO)
          AND (PRODFILI.CDFILIAL  = P_CDFILIAL)
          AND (PRODFILI.CDPRODUTO = R.CDPRODUTO)
          AND (NP.CDNUTRIENTE  = (SELECT MAX(CDPROTEINA) FROM PARAMGERAL)))
   ) LOOP
      V_NPU := NVL(CUR_PROTEINA.NPU,0);
   END LOOP;
   
   SELECT SUM(R.QTPRODLIQ)
     INTO V_PROTLIQU
     FROM TABLE (RECEITA_UTIL(P_CDFILIAL, P_CDSERVFILI, P_CDPRATO, P_CDFILAUXPRAT,'0', 'Z', P_CDPRATO,0,0,'N') ) R
          INNER JOIN NUTRPROD NP ON NP.CDPRODUTO = R.CDPRODUTO;

   IF V_CALORIAS = 0 OR V_CALORIAS IS NULL THEN
      V_NDPCAL := 0;
   ELSE
      V_NDPCAL := NVL(V_PROTLIQU,0) * NVL(V_NPU,0) * 4 / V_CALORIAS;
   END IF;

   RETURN(ROUND(V_NDPCAL, 2));

END;
/